Dr.Pata.com

Bajar Carpeta de Objetos Mime con todo su contenido

2009-12-31T08:14:00.001-06:00

Bueno estuve tratando de revisar algunos ejemplos de WebDynpro con Adobe Flex. Pero uno de los requisitos de estos ejemplos era contar con unos archivos swf que vienen en la carpeta nw7 del Contenedor Mime de SAP (eso se puede ver en la se80). Lo malo es que esa carpeta de nw7 solo viene en las versiones del ECC6 con EHP 1 o superior...
Asi que consultando con los patas. Uno de ellos tenia acceso a una version de esas y me pregunto que archivo queria , cuando le pedi que baje toda la carpeta: Error Fatal!!!. SAP no trae la opcion de bajar toda la carpeta. Buscando muchos sugieren usar una herramienta de SAP que requiere conectarse directamente al container de SAP, asi q ni hablar habia que programar algo.
Aqui les adjunto un programa para eso. Me base en el programa zggar_mime_tool que esta en wiki.sdn.sap.com

ZEFR_MIME_DOWN

*&---------------------------------------------------------------------*

*& Report  ZEFR_MIME_DOWN

*&

*&---------------------------------------------------------------------*

*&

*&

*&---------------------------------------------------------------------*

* Selection text :

* P_DIR       Directorio en disco

* P_DOWN     Grabar en disco

* P_FOLDER   Carpeta raiz

REPORT  zefr_mime_down.

PARAMETERS: p_folder  TYPE sdok_loid DEFAULT '41E73DAE02B43459E10000000A1552AC'.

PARAMETERS: p_dir(20) DEFAULT 'c:\nw7_mime'.

PARAMETERS: p_down AS CHECKBOX.

TYPES: BEGIN OF p_object,

         p_class  TYPE sdok_class,

         p_objid  TYPE sdok_docid,

       END OF p_object.

TYPES: BEGIN OF t_io_extended.

INCLUDE TYPE skwf_io.

INCLUDE TYPE sdokcomacs.

INCLUDE TYPE p_object.

TYPES: parent(250).

TYPES: END OF t_io_extended.

TYPES: tt_io_extended TYPE TABLE OF t_io_extended.

DATA: lt_ios_extended TYPE tt_io_extended.

DATA: l_folder  TYPE skwf_io.

DATA: lt_ios    TYPE skwf_ios,

      l_error   TYPE skwf_error.

DATA: l_io_object    TYPE sdokobject.

DATA: lt_context     TYPE TABLE OF sdokpropty,

      lt_components  TYPE TABLE OF sdokcomacs,

      lt_ascii       TYPE TABLE OF sdokcntasc,

      lt_bin         TYPE TABLE OF sdokcntbin.

DATA: wo_alv            TYPE REF TO cl_salv_table,

      wo_alv_functions  TYPE REF TO cl_salv_functions_list,

      wo_alv_columns    TYPE REF TO cl_salv_columns_table.

DATA: lt_alv_functions     TYPE salv_t_ui_func,

      l_alv_function_name  TYPE salv_de_function. " string.

DATA: l_dyna_func          TYPE string.

FIELD-SYMBOLS: <fs_io>           LIKE LINE OF lt_ios,

               <fs_io_extended>  LIKE LINE OF lt_ios_extended,

               <fs_component>    LIKE LINE OF lt_components,

               <fs_alv_function> LIKE LINE OF lt_alv_functions.

DATA: ls_ios_extended LIKE LINE OF lt_ios_extended.

DATA: phio LIKE sdokobject.

**********************************************************************

START-OF-SELECTION.

  PERFORM init_folder.

  PERFORM get_principal TABLES lt_ios_extended.

  LOOP AT lt_ios_extended INTO ls_ios_extended WHERE objtype = 'F'.

    p_folder = ls_ios_extended-objid.

    PERFORM get_principal TABLES lt_ios_extended.

  ENDLOOP.

  IF p_down = 'X'.

    MESSAGE ID '00' TYPE 'S' NUMBER '001' WITH 'start download'.

    PERFORM download.

  ENDIF.

**********************************************************************

END-OF-SELECTION.

  CALL METHOD cl_salv_table=>factory

    EXPORTING

      list_display = abap_false

    IMPORTING

      r_salv_table = wo_alv

    CHANGING

      t_table      = lt_ios_extended.

  wo_alv_functions = wo_alv->get_functions( ).

  wo_alv_functions->set_default( 'X' ).

  wo_alv_functions->set_all( 'X' ).

  lt_alv_functions = wo_alv_functions->get_functions( ).

  wo_alv_columns = wo_alv->get_columns( ).

  wo_alv_columns->set_optimize( 'X' ).

  wo_alv->display( ).

*&---------------------------------------------------------------------*

*&      Form  GET_PRINCIPAL

*&---------------------------------------------------------------------*

FORM get_principal TABLES t_ios_extended STRUCTURE ls_ios_extended.

  DATA: l_ios  TYPE TABLE OF skwf_io,

        s_ios  TYPE skwf_io,

        l_prop TYPE TABLE OF sdokpropty,

        s_prop TYPE sdokpropty.

  DATA: ls_ios_extended LIKE LINE OF lt_ios_extended.

  l_folder-objtype = 'F'.

  l_folder-class   = 'M_FOLDER'.

  l_folder-objid   = p_folder.

  CALL METHOD cl_skwf_folder_util=>ios_attach_get

    EXPORTING

      folder = l_folder

    IMPORTING

      ios    = lt_ios

      error  = l_error.

  CHECK l_error IS INITIAL.

  LOOP AT lt_ios ASSIGNING <fs_io>.

    APPEND INITIAL LINE TO t_ios_extended ASSIGNING <fs_io_extended>.

    MOVE-CORRESPONDING <fs_io> TO <fs_io_extended>.

    CLEAR  : l_io_object.

    REFRESH: lt_context,

             lt_components.

    MOVE-CORRESPONDING <fs_io> TO l_io_object.

    CALL FUNCTION 'SDOK_GET_PHIO_ACCESS'

      EXPORTING

        loio_object_id      = l_io_object

      IMPORTING

        phio_object_id      = phio

      TABLES

        context             = lt_context

        components          = lt_components

        file_content_ascii  = lt_ascii

        file_content_binary = lt_bin

      EXCEPTIONS

        not_existing        = 1

        no_physical_object  = 2

        not_authorized      = 3

        no_content          = 4

        bad_storage_type    = 5

        context_incomplete  = 6

        no_codepage_info    = 7

        bad_parameter       = 8

        OTHERS              = 9.

    IF sy-subrc = 2. sy-subrc = 0. ENDIF.

    IF sy-subrc <> 0.

      MESSAGE ID sy-msgid TYPE 'S' NUMBER sy-msgno

              WITH sy-msgv1 sy-msgv2 sy-msgv3 sy-msgv4.

      CHECK sy-subrc = 0.

    ENDIF.

    READ TABLE lt_components ASSIGNING <fs_component> INDEX 1.

    IF sy-subrc = 0.

      MOVE-CORRESPONDING <fs_component> TO <fs_io_extended>.

    ENDIF.

    IF phio IS NOT INITIAL.

      <fs_io_extended>-p_class = phio-class.

      <fs_io_extended>-p_objid = phio-objid.

    ENDIF.

    s_ios-objtype = 'F'.

    s_ios-class   = 'M_FOLDER'.

    s_ios-objid   = <fs_io_extended>-objid.

    CALL FUNCTION 'SKWF_IO_PROPERTIES_GET'

      EXPORTING

        io                = s_ios

      TABLES

        properties_result = l_prop.

    IF <fs_io_extended>-objtype = 'F'.

      READ TABLE l_prop INTO s_prop WITH KEY name = 'KW_RELATIVE_URL'.

      <fs_io_extended>-file_name  = s_prop-value.

    ENDIF.

    READ TABLE l_prop INTO s_prop WITH KEY name = 'KW_PARENT_FOLDER_ID'.

    READ TABLE lt_ios_extended INTO ls_ios_extended WITH KEY objid = s_prop-value.

    CONCATENATE ls_ios_extended-parent '\' ls_ios_extended-file_name INTO <fs_io_extended>-parent.

  ENDLOOP.

ENDFORM.                    " GET_PRINCIPAL

*&---------------------------------------------------------------------*

*&      Form  download

*&---------------------------------------------------------------------*

FORM download .

  DATA: p_file TYPE  sdok_filnm,

        p_list TYPE string,

        v_dir  TYPE  rlgrap-filename.

  DATA: l_phio TYPE  skwf_io.

  MOVE  p_dir TO v_dir.

  TRANSLATE v_dir TO LOWER CASE.

  CALL FUNCTION 'GUI_CREATE_DIRECTORY'

    EXPORTING

      dirname = v_dir

    EXCEPTIONS

      failed  = 1

      OTHERS  = 2.

  CONCATENATE p_dir '\' '_list' INTO p_file.

  CONDENSE p_file.

  MOVE p_file TO p_list.

  CALL FUNCTION 'GUI_DOWNLOAD'

    EXPORTING

      filename                = p_list

    TABLES

      data_tab                = lt_ios_extended

    EXCEPTIONS

      file_write_error        = 1

      no_batch                = 2

      gui_refuse_filetransfer = 3

      invalid_type            = 4

      no_authority            = 5

      unknown_error           = 6

      header_not_allowed      = 7

      separator_not_allowed   = 8

      filesize_not_allowed    = 9

      header_too_long         = 10

      dp_error_create         = 11

      dp_error_send           = 12

      dp_error_write          = 13

      unknown_dp_error        = 14

      access_denied           = 15

      dp_out_of_memory        = 16

      disk_full               = 17

      dp_timeout              = 18

      file_not_found          = 19

      dataprovider_exception  = 20

      control_flush_error     = 21

      OTHERS                  = 22.

  IF sy-subrc <> 0.

    MESSAGE ID sy-msgid TYPE sy-msgty NUMBER sy-msgno

            WITH sy-msgv1 sy-msgv2 sy-msgv3 sy-msgv4.

  ENDIF.

  DESCRIBE TABLE lt_ios_extended.

  CHECK sy-tfill <> 0.

  MESSAGE ID '00' TYPE 'S' NUMBER '001' WITH 'start create directory'.

  LOOP AT lt_ios_extended INTO ls_ios_extended WHERE objtype = 'F'.

    IF ls_ios_extended-parent IS INITIAL.

      CONCATENATE p_dir

                  '\' ls_ios_extended-file_name

             INTO v_dir.

    ELSE.

      CONCATENATE p_dir

                  ls_ios_extended-parent

                  '\' ls_ios_extended-file_name

             INTO v_dir.

    ENDIF.

    CALL FUNCTION 'GUI_CREATE_DIRECTORY'

      EXPORTING

        dirname = v_dir

      EXCEPTIONS

        failed  = 1

        OTHERS  = 2.

  ENDLOOP.

  MESSAGE ID '00' TYPE 'S' NUMBER '001' WITH 'start download files'.

  LOOP AT lt_ios_extended INTO ls_ios_extended WHERE objtype <> 'F'.

    l_phio-objtype = 'P'.

    l_phio-class   = ls_ios_extended-p_class.

    l_phio-objid   = ls_ios_extended-p_objid.

    CONCATENATE p_dir

                ls_ios_extended-parent

                '\' ls_ios_extended-file_name

           INTO p_file.

    CONDENSE p_file.

    CALL FUNCTION 'SKWV_KWUI_DOC_EXPORT'

      EXPORTING

        phio     = l_phio

        filename = p_file.

    MESSAGE ID '00' TYPE 'S' NUMBER '001'

            WITH 'file' p_file 'process sucessfully'.

  ENDLOOP.

  MESSAGE ID '00' TYPE 'S' NUMBER '001' WITH 'end download files'.

ENDFORM.                    " download

*&---------------------------------------------------------------------*

*&      Form  init_folder

*&---------------------------------------------------------------------*

FORM init_folder .

  DATA: l_ios  TYPE TABLE OF skwf_io,

      s_ios  TYPE skwf_io,

      l_prop TYPE TABLE OF sdokpropty,

      s_prop TYPE sdokpropty.

  APPEND INITIAL LINE TO lt_ios_extended ASSIGNING <fs_io_extended>.

  s_ios-objtype = 'F'.

  s_ios-class   = 'M_FOLDER'.

  s_ios-objid   = p_folder.

  CALL FUNCTION 'SKWF_IO_PROPERTIES_GET'

    EXPORTING

      io                = s_ios

    TABLES

      properties_result = l_prop.

  MOVE-CORRESPONDING s_ios TO <fs_io_extended>.

  READ TABLE l_prop INTO s_prop WITH KEY name = 'KW_RELATIVE_URL'.

  <fs_io_extended>-file_name  = s_prop-value.

ENDFORM.                    " init_folder

Blogs de SAP

2009-11-23T22:01:00.000-06:00

Andaba buscando inspiración sobre como blogear, y se me ocurrio buscar algunos blogs de SAP para ver como se ven. Al final esto es lo que encontre:

http://nw70.blogspot.com/

http://sapbasisguru.wordpress.com/

http://sap-install.blogspot.com/

http://studysap.youngmediaworld.info/

http://sap-erp-consultants.blogspot.com/

http://www.sapsrm.net/

http://www.sapbapi.com/

http://saptraininginstitutes.blogspot.com/

http://seguridadsap.blogspot.com/

http://www.seguridadsap.com/

http://www.infosysblogs.com/

http://todosap.blogspot.com/

http://sap-srm-articles.blogspot.com

http://www.richardsantos.net/2009/10/22/sap-how-to-activate-sap-webgui/

http://www.abapprogramming.net/

http://atejada.blogspot.com

http://ramgv-sap.blogspot.com/

http://danielpanaro.wordpress.com/

http://abapbet.blogspot.com/

http://www.richardsantos.net/

http://sapblog.rmtiwari.com/

http://sapabap-interview.blogspot.com/

http://www.abapcode.info/

http://abap-gallery.blogspot.com/

http://blog.danmcweeney.com/category/abap

http://abaplovers.blogspot.com/

http://help-abap.blogspot.com/

http://sapport.blogspot.com/

http://nigeljames.wordpress.com/

http://abaponline.net/

http://nigeljam.es/

Field-Symbols

2009-11-16T07:54:00.012-06:00

Declara una variable simbólica con el nombre . En tiempo de ejecución, se puede asignar una variable concreta por medio de la sentencia ASSIGN.

Cualquier operación que se realice usando la variable simbólica afectará directamente a la variable asignada a ella.

Syntaxis:
FIELD-SYMBOLS <fs>[<type>|STRUCTURE <s> DEFAULT <wa>].

Uso:

Como estructura en lugar de work area.
En programación dinámica.

Loop a todos los campos de una estructura

2009-11-16T07:49:00.003-06:00

Codigo para recorrer los campos de una estructura de forma dinámica. Muy util cuando no conocemos de antemano la estructura...

DO.
ASSIGN COMPONENT sy-index OF STRUCTURE l_struct TO .
IF IS ASSIGNED.
" Leer información del campo
DESCRIBE FIELD TYPE l_type.

...

ELSE.
EXIT.
ENDIF.

UNASSIGN: .
ENDDO.

Algo sobre SAP

2009-11-15T22:56:00.010-06:00

Estuve pensando en publicar algo de la historia de SAP, algo que describa la trayectoria y el actual posicionamiento de este mostruo hoy en día...

SAP fue fundada en 1972 en la Ciudad de Mannheim, Alemania, por algunos de los antiguos empleados de IBM (Claus Wellenreuther, Hans-Werner Hector, Klaus Tschira, Dietmar Hopp y Hasso Plattner) bajo el nombre de "SAP Systemanalyse, Anwendungen und Programmentwicklung". El nombre fue tomado de la división en la que trabajaban en IBM.

Software Top100

PCSL Corporate Services Limited

Lo básico sobre DEBUG

2009-11-15T22:09:00.013-06:00

Para iniciar a debugear debemos de colocar un break point. Esto lo hacemos con una de las siguientes formas:

El comando de linea /h
El comando BREAK-POINT
El comando BREAK
Fijar un Break-Point de sesion con el boton
Con un acceso directo del tipo Comando del sistema /h
Un job ejecutado con el comando de linea jdbg
Con un bucle Do infinito y la tx SM50

Crear acceso directo del tipo Comando del sistema/h

Para empezar usamos el icono

Aparece la pantalla llenamos los datos como se muestra y se creara un archivo en el escritorio. Para usarlo basta con arrastrarlo sobre la ventana de SAP que queremos debugear, es muy util cuando se trata de un popup ya que en ese momento no se tiene acceso a la linea de comandos.

El nuevo Editor ABAP

2009-10-31T00:58:00.010-06:00

Para empezar menciono que al configurar como predeterminado el Nuevo Editor ABAP junto con el Nuevo Debug se tiene muchas ventajas.
El editor tiene un sistema de resaltado de la sintaxis parametrizable, resaltado del bloque actual, colores para diferenciar la sintaxis, plantillas de código, portapapeles múltiple, búsqueda incremental, selección de bloques, código sugerido, funcionalidad pretty print extendida, previsualización de la impresión embebida, guardado del codigo en html, lineas numeradas, indicador de cambios, atajos de teclado parametrizables, etc.
Para activar el nuevo editor empezamos en alguna de las siguientes transacciones: SE38, SE37, SE24, SE37. Ir a Utilidades > Opciones ...

DEBUG

2009-10-31T00:34:00.012-06:00

El tema "debug" es basico para todo CONSULTOR SAP , ademas tiene aspectos muy sofisticados que pueden ayudar a facilitar encontrar solucion o causa de algun problema. Aquí enumero algunos temas que pueden presentar.

El debug básico break-point y /h
Debug a ventanas popup
Debug en procesos de fondo
Debug en jobs
Llenar datos de prueba de funcionesSE37
Debug para modificar datos desde la SE16
Debug para modificar en QAS

Aprender ABAP

2009-10-30T23:57:00.008-06:00

Pienso que como en todas las demas cosas de la vida, se aprende mas HACIENDO que VIENDO, o LEYENDO o si DEJAS QUE OTROS TE LO CUENTEN.

Algunos Tips que recomiendo para aprender de forma autodidacta sin perder el interes:

Los manuales de la academia de ABAP son un buen punto de partida. Mejor aun si solo sigues los ejercicios practicos al final de cada unidad.
Aprende a debugear y debugea todo lo que se te ocurra.
Si tienes experiencia como funcional, comienza implementando User-Exit, Formulas, etc. Generalmente requieren programacion muy espeficica.
Si tienes experiencia como programador, programa funciones que imagines que te pueden servir en muchos programas.
Aprende de tus experiencias y de las experiencias de los demas; respalda copias de tus programas y de los programas de otros.
Si no tienes experiencia previa en SAP, te recomiendo que aprendas las transacciones de manipulacion de documentos. Ejemplo Datos maestro de material (MM01/02/03), Datos maestro de cliente (XD01/02/03), Pedido de compra (ME21/22/23), Orden de Venta (VA01/02/03), Contrato(VA41/42/43). Luego haces el mapeo de algunos campos y te planteas reportes (listados) de esos documentos.